set CURR_OS = `uname -s`

# If current operating system is NT, set alias to call awk95 as "awk".
if ($CURR_OS == "WINDOWS_NT") then
   alias awk '$EDIR_PATH/nt/bin/awk95'
endif

if ($?GENESIS_TMP) then
   set TMP = $GENESIS_TMP
else if ($?GENESIS_DIR) then
   set TMP = $GENESIS_DIR/tmp
else
   set TMP = /genesis/tmp
endif

# Set the INFO alias and the tmp INFO file.
set INFO = $TMP/info
alias DO_INFO 'COM info,out_file=$INFO,write_mode=replace,args=\!:*;source $INFO; rm $INFO'

# Set up gui data and response files.
set GUI_DATA = $TMP/gui_data.$$
set GUI_RESP = $TMP/gui_resp.$$
alias o 'echo \!:* >> $GUI_DATA'
alias do_gui gui "$GUI_DATA > $GUI_RESP; source $GUI_RESP; \rm $GUI_RESP $GUI_DATA"
alias o_tooling 'echo -n >! $GUI_DATA; o WIN 200 200;o FONT $TITLE_FONT;o FG 999999;o BW 1;o LABEL Genesis Automated Tooling'
set TITLE_FONT = "hbr18"
set NORM_FONT  = "hbr14"
set HINT_FONT  = "hbi14"
   
# Check to see if $GENESIS_EDIR is local path or absolute. Set "EDIR_PATH" accordingly).
if ($GENESIS_EDIR =~ /* || $GENESIS_EDIR =~ ?:*) then
   set EDIR_PATH = ($GENESIS_EDIR)
else
   set EDIR_PATH = ($GENESIS_DIR/$GENESIS_EDIR)
endif 

# Find out the user name.
COM get_user_name
set USER = "$COMANS"

if ($?JOB) then
   if ($?FORM) then
      set IN_PROGRESS_COLOR = 999922 
      set COMPLETE_COLOR    = 229922 
      set FAILED_COLOR      = 992222
      set RERUN_COLOR       = 148599
      set TITLE_FONT        = 
      COM read_form,job=$JOB,form=genform1,elem=job_path
      set JOB_PATH = "$COMANS"
   else
      set JOB_PATH = "a5/b6/c7"
   endif 

   if (! -e "$JOB_PATH") then
      set JOB_PATH = `$EDIR_PATH/misc/dbutil path jobs $JOB`
   endif

   set CONT_FILE = "$JOB_PATH/user/control_log"
   alias log 'echo $DATE \!:1 $USER":"\!:2-* >> $CONT_FILE'

   # Source form info. file.
   source $JOB_PATH/forms/genform1/def/form_info.source

   alias calc_date 'set DATE = `date "+%d %b %y - %H:%M"`'

   alias set_in_progress \
      'calc_date;\\
       COM edit_form,job=$JOB,form=\!:1,elem=\!:2,color=$IN_PROGRESS_COLOR;\\
       COM edit_form,job=$JOB,form=\!:1,elem=\!:2"_usr",value=$USER;\\
       COM edit_form,job=$JOB,form=\!:1,elem=\!:2"_dte",value=In Progress;\\
       log START \!:1"."\!:2-*'
   alias set_complete \
      'calc_date;\\
       COM edit_form,job=$JOB,form=\!:1,elem=\!:2,color=$COMPLETE_COLOR;\\
       COM edit_form,job=$JOB,form=\!:1,elem=\!:2"_dte",value=$DATE;\\
       log "DONE " \!:1"."\!:2-*'
   alias save_job \
      'COM save_job,job=$JOB; source $JOB_PATH/forms/genform1/def/save_time'
endif

