@echo off

REM  (C)Copyright GEIT
REM  Ver 1.0
REM  2012.11.26
REM
REM  使用前请确认ActiveX模块名称是否正确。
REM  set modelName=*****.ocx/*****.dll,...

if "%1"=="/?" goto HELPME
if "%1"=="?" goto HELPME
if "%1"=="-?" goto HELPME

REM -----------------------------------------------
set modelName=IDCardReader.ocx
set modelDLL=JCJP_API.dll sdtapi.dll WltRS.dll
REM -----------------------------------------------

if /i %PROCESSOR_IDENTIFIER:~0,3%==x86 (
	goto ST000
) else (
	goto ST001
)

:ST000

echo 注销控件：%modelName%
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\system32\%%i regsvr32 /s /u %SystemRoot%\system32\%%i 
echo.
echo 删除系统路径下的控件：%modelName%
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\system32\%%i del %SystemRoot%\system32\%%i
echo 注销控件完成。
echo.

:CP000
echo 复制 %modelName% 到 %SystemRoot%\system32 下
echo.
FOR /D %%i IN (%modelName%) DO if exist .\%%i copy .\%%i  %SystemRoot%\system32\%%i
if errorlevel 1 goto ERR000
echo.

echo 复制 %modelDLL% 到 %SystemRoot%\system32 下
echo.
FOR /D %%i IN (%modelDLL%) DO if exist .\%%i copy .\%%i  %SystemRoot%\system32\%%i
if errorlevel 1 goto ERR000
echo.

echo 注册新的 %modelName%
echo.
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\system32\%%i regsvr32 /s %SystemRoot%\system32\%%i
if errorlevel 1 goto ERR000

echo 32位系统操作结束。
echo.
echo.
goto EXIT000


:ST001

echo 注销控件：%modelName%
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\SysWOW64\%%i regsvr32 /s /u %SystemRoot%\SysWOW64\%%i 
echo.
echo 删除系统路径下的控件：%modelName%
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\SysWOW64\%%i del %SystemRoot%\SysWOW64\%%i
echo 注销控件完成。
echo.

:CP001
echo 复制 %modelName% 到 %SystemRoot%\SysWOW64 下
echo.
FOR /D %%i IN (%modelName%) DO if exist .\%%i copy .\%%i  %SystemRoot%\SysWOW64\%%i
if errorlevel 1 goto ERR000
echo.

echo 复制 %modelDLL% 到 %SystemRoot%\SysWOW64 下
echo.
FOR /D %%i IN (%modelDLL%) DO if exist .\%%i copy .\%%i  %SystemRoot%\SysWOW64\%%i
if errorlevel 1 goto ERR000
echo.

echo 注册新的 %modelName%
echo.
FOR /D %%i IN (%modelName%) DO if exist %SystemRoot%\SysWOW64\%%i regsvr32 /s %SystemRoot%\SysWOW64\%%i
if errorlevel 1 goto ERR000

echo 64位系统操作结束。
echo.
echo.
goto EXIT000

:ERR000
echo.
echo 无法复制新的%modelName%，请关闭IE再执行此文件。
echo.
goto EXIT000

:HELPME
echo  **************************************************
echo  *         (C)Copyright GEIT                      *
echo  *                  Ver 1.1                       *
echo  *                2007.09.01                      *
echo  *                                                *
echo  *    ***使用前请确认ActiveX模块名称是否正确***   *
echo  *       set modelName=*****.ocx/*****.dll        *
echo  *                                                *
echo  * 2006.03.16 新增批量复制、注册、注销功能        *
echo  *            使用了DOS脚本的FOR命令              *
echo  *                                                *
echo  **************************************************
goto EXIT000

:EXIT000
rem pause>nul
pause
